home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Gold Medal Software 4
/
Gold Medal Software - Volume 4 (Gold Medal) (1994).iso
/
menuts
/
hdmm468.arj
/
CCC.BAT
< prev
next >
Wrap
DOS Batch File
|
1994-04-18
|
5KB
|
135 lines
@ECHO OFF
CLS
ECHO You have 30 seconds to answer each question or CCC will use a default answer!
ECHO
C:
IF %1. == C. GOTO :CHKDSK
:TBAV
C:
IF NOT EXIST \TBAV\TBSCAN.EXE GOTO :FPROT
ECHO Check/Clean/Compress is about to check out your ROOT directory.
ECHO
GET C "TBSCANning for virus infections in 30 seconds ... (A)ll (F)ast (S)kip " /W30
IF %GET%. == C. GOTO :CHKDSK
IF %GET%. == N. SET GET=S
IF %GET%. == S. GOTO :FPROT
IF %GET%. == A. TBSCAN C:\ AF NS
IF %GET%. == F. TBSCAN C:\ NS
IF NOT %GET%. == A. IF NOT %GET%. == F. TBSCAN C:\ NS
IF ERRORLEVEL 1 GOTO :SCANFAIL
:FPROT
C:
IF NOT EXIST \SECURITY\F-PROT.EXE GOTO :SCAN
ECHO Check/Clean/Compress is about to check out your ROOT directory.
ECHO
GET C "F-Prot Scanning for virus infections in 30 seconds ... (A)ll (F)ast (S)kip " /W30
IF %GET%. == C. GOTO :CHKDSK
IF %GET%. == N. SET GET=S
IF %GET%. == S. GOTO :SCAN
IF %GET%. == A. F-PROT C:\ /ALL /NOSUB
IF %GET%. == F. F-PROT C:\ /NOSUB
IF NOT %GET%. == A. IF NOT %GET%. == F. F-PROT C:\ /NOSUB
IF ERRORLEVEL 1 GOTO :SCANFAIL
:SCAN
IF NOT EXIST \SECURITY\SCAN.EXE GOTO :CHKDSK
ECHO Check/Clean/Compress is about to check out your ROOT directory.
ECHO
GET C "SCANning for virus infections in 30 seconds ... (A)ll (F)ast (S)kip " /W30
IF %GET%. == C. GOTO :CHKDSK
IF %GET%. == N. SET GET=S
IF %GET%. == S. GOTO :CHKDSK
IF %GET%. == A. SCAN C:\ /M /A /CHKHI
IF %GET%. == F. SCAN C:\ /FAST
IF NOT %GET%. == A. IF NOT %GET%. == F. SCAN C:\ /M /CHKHI
IF ERRORLEVEL 1 GOTO :SCANFAIL
:CHKDSK
CHKDSK
ECHO
ECHO If you saw any errors please answer Yes by pressing a Y
GET C "Should I run CHKDSK /F (To repair any DISK errors) (Y/N)? " YN /W30
IF %GET%. == C. GOTO :CHKDSK
IF %GET%. == Y. CHKDSK /F
IF NOT EXIST C:\PCTOOLS\DISKFIX.EXE GOTO :SCHECK
GET C "Should I run C:\PCTOOLS\DISKFIX (To repair errors) (Y/N)? " YN /W30
IF %GET%. == C. GOTO :EXIT
IF %GET%. == Y. C:\PCTOOLS\DISKFIX
:SCHECK
C:
IF EXIST C:\STACKER\STACKED.D D:
IF EXIST C:\STACKER\STACKED.E E:
IF EXIST C:\STACKER\STACKED.F F:
IF NOT EXIST C:\STACKER\SCHECK.* GOTO :CHECK
C:\STACKER\SCHECK
ECHO
ECHO If you saw any errors please answer Yes by pressing a Y
GET C "Should I run C:\STACKER\SCHECK /F (To repair errors) (Y/N)? " YN /W30
IF NOT %GET%. == Y. GOTO :CHECK
C:\STACKER\SCHECK /F
:CHECK
IF NOT EXIST C:\STACKER\CHECK.* GOTO :NOSTAC
C:\STACKER\CHECK
ECHO
ECHO If you saw any errors please answer Yes by pressing a Y
GET C "Should I run C:\STACKER\CHECK /F (To repair errors) (Y/N)? " YN /W30
IF NOT %GET%. == Y. GOTO :NOSTAC
C:\STACKER\CHECK /F
:NOSTAC
C:
ECHO
ECHO Especially if you repaired any errors above, answer Yes with a Y
GET C "Should I restart Check Clean Compress (To retest for errors) (Y/N)? " NY /W30
IF %GET%. == Y. GOTO :CHKDSK
ECHO
CD\
IF EXIST PCT?????.FIX GOTO :CHKFIX
IF EXIST FILE????.CHK GOTO :CHKFIX
GOTO :DEFRAG
:CHKFIX
ECHO I found recovered file(s) (PCT????.FIX and/or FILE????.CHK)!
ECHO Once you start viewing the file(s) press Q to quit each file view.
ECHO To exit LIST after viewing the last file press ESC.
GET C "Do you want to view these recovered files now (Y/N)? " NY /W60
ECHO
IF NOT %GET%. == Y. GOTO :DEFRAG
IF EXIST FILE????.CHK LIST FILE????.CHK
IF EXIST PCT?????.FIX LIST PCT?????.FIX
ECHO
ECHO
GET C "Selectively delete PCT?????.FIX & FILE????.CHK files now (Y/N)? " NY /W30
IF %GET%. == Y. PDEL FILE????.CHK,PCT?????.FIX /P
:DEFRAG
C:
IF NOT EXIST \PCTOOLS\COMPRESS.* GOTO :SDEFRAG
ECHO Should I run C:\PCTOOLS\COMPRESS to defragment Hard Drive (Y/N/U/S/F/C)?
GET C " (Y)es, (N)o, (U)nfragment, (S)td full, (F)ull complete, (C)ompress? " YNUSFC /W60
IF %GET%. == N. GOTO :SDEFRAG
IF EXIST C:\STACKER\PRN IF NOT EXIST C:\STACKER\STACKER.? SET GET=C
IF EXIST C:\STACKER\STACKER.D D:
IF EXIST C:\STACKER\STACKER.E E:
IF EXIST C:\STACKER\STACKER.F F:
IF EXIST C:\STACKER\STACKER.L L:
IF %GET%. == C. C:\PCTOOLS\COMPRESS
IF %GET%. == F. C:\PCTOOLS\COMPRESS /CF /OO /SF
IF %GET%. == S. C:\PCTOOLS\COMPRESS /CF /OS /SF
IF %GET%. == U. C:\PCTOOLS\COMPRESS /CU /OS /SF
IF %GET%. == Y. IF EXIST \FULL C:\PCTOOLS\COMPRESS /CF /OO /SF
IF %GET%. == Y. IF NOT EXIST \FULL C:\PCTOOLS\COMPRESS /CU /OS /SF
:SDEFRAG
C:
IF NOT EXIST C:\STACKER\SDEFRAG.* GOTO :EXIT
IF EXIST C:\STACKER\STACKED.D D:
IF EXIST C:\STACKER\STACKED.E E:
IF EXIST C:\STACKER\STACKED.F F:
GET C "Should I run C:\STACKER\SDEFRAG to defragment Stacker Drive (Y/N)? " NY /W30
IF %GET%. == Y. C:\STACKER\SDEFRAG
GOTO :EXIT
:SCANFAIL
ECHO ***** WARNING *****
ECHO -
ECHO One of the Virus scanners has detected a problem! Call Darrell in M.I.S. NOW!
ECHO -
PAUSE
:EXIT
C: